* Richard A. DeVenezia 11/27/2000;
* draw minor ticks between some custom major ticks;

data noise;
  dB = -21;
  do until (dB > 140);

    readings = PDF ('NORMAL', dB, 40, 25) + ranuni(0)/300;
    readings = int (1000 * readings);

    output;

    if -7 <= dB <= 0 then
      dB ++ 1;
    else
      dB ++ 1+int(7*ranuni(0));
  end;
  label dB = 'decibels (dB)';
  label readings = 'Number of readings';
run;

data tickAnnotate;
  retain xsys '2' ysys '1'; * read the SAS/Graphics manual, annotate chapters;
  length function $8;
  do x = -6 to -1;
    y =  0; function = 'move'; output;
    y = -1; function = 'draw'; output;
  end;
run;

goptions reset=(all);

axis1 order = (-21, -7, 0, 28, 56, 84, 112, 140) ;
axis2 minor = none label=(angle=90);

symbol1 font=marker i=step value=U height=1pct c=black;

title "Minor tick marks drawn with annotate";

ods html path='c:\temp\report' body='gplot-anno.html';

goptions target=gif160 ftext=simplex xpixels=256 ypixels=256;

proc gplot data=noise anno=tickAnnotate;
  plot readings * dB
  / haxis = axis1
    vaxis = axis2
  ;
run;
quit;

ods html close;